Why is stage not available in the following example?

Question

I am working with Flash Professional IDE. Referencing the classes below, if I set the class property of the FLA to testingsub1 (ignoring Main) the code works fine. But if I set the class to Main the code dies at stage.addChild(container); of testing with "TypeError: Error #1009: Cannot access a property or method of a null object reference.".

This goes against my understanding that the stage is global and always available to have display objects added directly. Any insight and solution?

package {
    //import com.idtlw.iso.utils.Const;
    import flash.display.*;

    public class testingsub1 extends testing {

        public function testingsub1() {
            trace("initializing testing sub 1");
            var container:Sprite=new Sprite();

            var test1:Sprite=new Sprite();

            container.addChild(test1);
        }
    }
}

package {
    import flash.display.*;

    public class testing extends Sprite {

        public function testing() {
            trace("initializing testing");
            var container:Sprite=new Sprite();

            var test1:testreg1=new testreg1();

            container.addChild(test1);

            stage.addChild(container);
        }
    }
}

package 
{

        import flash.display.*;

        public class Main extends Sprite
        {
                public function Main ()
                {
                        var test1:Sprite=new Sprite();
                        stage.addChild(test1);

                        var tester:testingsub1=new testingsub1();
                }
        }
}

The stage is not globally accessible. The stage property of a DisplayObject is null unless it is attached to the display list hierarchy of the stage. — prototypical
I’d argue that—other than the main display object—nothing should ever need to access stage directly. We are talking about components that could be nested in many possible situation; a component shouldn’t be able to add another component to the stage directly. — poke

Vesper Vesper · Accepted Answer · 2013-11-23T11:02:18

If you'd dwell in FlashDevelop tutorials, you'll find a tricky line of code:

if (stage) init(); else addEventListener(Event.ADDED_TO_STAGE,init);

This means that stage is not always available even to the Main class. Add this line, create a function init(e:Event=null):void putting any code that requires access to stage there, and you're set.

About your headline question - no class have stage available in the constructor by design, even if an object is placed to the stage at design time and it has a custom constructor, you cannot get valid reference to stage within that constructor. The stage property is filled only after the object has been added to a display list of an object that has it filled, or to stage.

Why is stage not available in the following example?

2 Answers