InnoTools Downloader not working with Inno 5.5

Question

On the recommendation of several posts here on SO, I've been working with the InnoTools Downloader to try to install a 3rd party dependency for our app during the Install script in Inno setup.

Unfortunately the InnoTools Downloader hasn't been updated in a few years, and is starting to look like it's incompatible with the current Inno Tools setup (5.5.2 (u) on my machine at present). The PChar parameters in ITD have been replaced by PAnsiChar parameters, and when I try to run the various ITD_xxx procedures it gives me varying degrees of fail:

ITD_DownloadFiles gives a type mismatch error and won't compile in Inno Setup
ITD_DownloadFile compiles, but the file that shows up is 6KB in length and not runnable.

Has anyone gotten ITP to run with newer Inno (post-5.3.0) unicode versions? Or should I look around for another solution?

EDIT Just to clarify things a bit, I have tried going into the it_download.iss file and replacing all instances of PChar with PAnsiChar. This got me past the compile errors when I first tried to integrate ITD with my setup script.

Here is a sample section of the Inno script:

[Code]
procedure InitializeWizard();
begin
  ITD_Init; // initialize the InnoTools Downloader
  // install 3rd party tool (ex. Git) from the internet.
  if ITD_DownloadFile('http://git-scm.com/download/win',expandconstant('{tmp}\GitInstaller.exe'))=ITDERR_SUCCESS then begin
     MsgBox(expandconstant('{tmp}\GitInstaller.exe'), mbInformation, MB_OK);
     Exec(ExpandConstant('{tmp}\GitInstaller.exe'), '', '', SW_SHOW, ewWaitUntilTerminated, tmpResult);
  end
end;

When this is run, it will bring up a dialog stating where it "downloaded" and stored the file -- on my machine it's in a subdirectory of c:\Users\\AppData\Local\Temp. This file is 6KB, as opposed to the file downloaded from http://git-scm.com/download/win, which is currently 15,221KB.

The ITP_DownloadAfter method gives a similar result.

"When I try to run" without showing us what you're doing isn't helpful, and neither is "gives a type mismatch error and won't compile" without the specific error message and line that is generating the error. Pre-Delphi 2009 PChar is the equivalent of D2009 and later PAnsiChar, but without specifics of the problem you're having it's hard to recommend a solution. — Ken White
Except replacement of PChar to PAnsiChar you must replace string with AnsiString. — TLama
@KenWhite - Thanks - I just added a [code] section to describe what I've tried so far. — eb1
@TLama - Thanks. I had done the PChar->PAnsiChar replace in the it_download.iss file; I just replaced the strings with AnsiStrings. Doesn't look like it helped any. :-( I found another Inno plugin that I might look into as an alternative if I can't get this running (here: mitrich.net23.net/?/inno-download-plugin.html). — eb1
It works for me. I've just replaced PChar with PAnsiChar and string with AnsiString and tried the code you posted. The problem is now that you're downloading a web site instead of a GIT installer binary. Check the content of the downloaded file. It's a HTML document. — TLama

TLama TLama · Accepted Answer · 2013-10-17T20:03:30

Except replacing all PChar type occurrences with PAnsiChar you will need to replace all occurrences of string type with AnsiString in the it_download.iss file. The next problem is the URL you're trying to get. The size of a file differs from expectation, because you are downloading a HTML document instead of the binary file on which that site redirects. So, if you have your ITD ready for Unicode, change the URL in your script to a direct binary URL. Note, that I didn't used HTTPS because ITD doesn't currently support SSL. A code proof may look like this:

[Code]
const
  GitSetupURL = 'http://msysgit.googlecode.com/files/Git-1.8.4-preview20130916.exe';

procedure InitializeWizard;
var
  Name: string;
  Size: Integer;
begin
  Name := ExpandConstant('{tmp}\GitInstaller.exe');

  ITD_Init;  
  if ITD_DownloadFile(GitSetupURL, Name) = ITDERR_SUCCESS then
  begin
    if FileSize(Name, Size) then
      MsgBox(Name + #13#10 + 'Size: ' + IntToStr(Size) + ' B',
        mbInformation, MB_OK)
    else
      MsgBox('FileSize function failed!', mbError, MB_OK);
  end;
end;

InnoTools Downloader not working with Inno 5.5

1 Answers