How to go about creating a prolog program that can work backwards to determine steps needed to reach a goal

Question

I'm not sure what exactly I'm trying to ask. I want to be able to make some code that can easily take an initial and final state and some rules, and determine paths/choices to get there.

So think, for example, in a game like Starcraft. To build a factory I need to have a barracks and a command center already built. So if I have nothing and I want a factory I might say ->Command Center->Barracks->Factory. Each thing takes time and resources, and that should be noted and considered in the path. If I want my factory at 5 minutes there are less options then if I want it at 10.

Also, the engine should be able to calculate available resources and utilize them effectively. Those three buildings might cost 600 total minerals but the engine should plan the Command Center when it would have 200 (or w/e it costs).

This would ultimately have requirements similar to 10 marines @ 5 minutes, infantry weapons upgrade at 6:30, 30 marines at 10 minutes, Factory @ 11, etc...

So, how do I go about doing something like this? My first thought was to use some procedural language and make all the decisions from the ground up. I could simulate the system and branching and making different choices. Ultimately, some choices are going quickly make it impossible to reach goals later (If I build 20 Supply Depots I'm prob not going to make that factory on time.)

So then I thought weren't functional languages designed for this? I tried to write some prolog but I've been having trouble with stuff like time and distance calculations. And I'm not sure the best way to return the "plan".

I was thinking I could write:

depends_on(factory, barracks)
depends_on(barracks, command_center)
builds_from(marine, barracks)
build_time(command_center, 60)
build_time(barracks, 45)
build_time(factory, 30)
minerals(command_center, 400)
...
build(X) :- 
  depends_on(X, Y),
  build_time(X, T),
  minerals(X, M),
...

Here's where I get confused. I'm not sure how to construct this function and a query to get anything even close to what I want. I would have to somehow account for rate at which minerals are gathered during the time spent building and other possible paths with extra gold. If I only want 1 marine in 10 minutes I would want the engine to generate lots of plans because there are lots of ways to end with 1 marine at 10 minutes (maybe cut it off after so many, not sure how you do that in prolog).

I'm looking for advice on how to continue down this path or advice about other options. I haven't been able to find anything more useful than towers of hanoi and ancestry examples for AI so even some good articles explaining how to use prolog to DO REAL THINGS would be amazing. And if I somehow can get these rules set up in a useful way how to I get the "plans" prolog came up with (ways to solve the query) other than writing to stdout like all the towers of hanoi examples do? Or is that the preferred way?

My other question is, my main code is in ruby (and potentially other languages) and the options to communicate with prolog are calling my prolog program from within ruby, accessing a virtual file system from within prolog, or some kind of database structure (unlikely). I'm using SWI-Prolog atm, would I be better off doing this procedurally in Ruby or would constructing this in a functional language like prolog or haskall be worth the extra effort integrating?

I'm sorry if this is unclear, I appreciate any attempt to help, and I'll re-word things that are unclear.

As a general technique one can apply shortest path algorithms to a problem of reaching a desired state. In some cases working backwards from the desired state to a known starting point is more efficient than "forward" search (see this Prolog example illustrating efficiency of one direction over the other). — hardmath
On the language integration side, there are several Prolog or Prolog-like implementations in Ruby. e.g. see here for a recently updated one. — hardmath
Are you refering to Backword chianing? en.wikipedia.org/wiki/Backward_chaining — bogs

mat mat · Accepted Answer · 2013-09-03T21:40:32

Your question is typical and very common for users of procedural languages who first try Prolog. It is very easy to solve: You need to think in terms of relations between successive states of your world. A state of your world consists for example of the time elapsed, the minerals available, the things you already built etc. Such a state can be easily represented with a Prolog term, and could look for example like time_minerals_buildings(10, 10000, [barracks,factory])). Given such a state, you need to describe what the state's possible successor states look like. For example:

state_successor(State0, State) :-
     State0 = time_minerals_buildings(Time0, Minerals0, Buildings0),
     Time is Time0 + 1,
     can_build_new_building(Buildings0, Building),
     building_minerals(Building, MB),
     Minerals is Minerals0 - MB,
     Minerals >= 0,
     State = time_minerals_buildings(Time, Minerals, Building).

I am using the explicit naming convention (State0 -> State) to make clear that we are talking about successive states. You can of course also pull the unifications into the clause head. The example code is purely hypothetical and could look rather different in your final application. In this case, I am describing that the new state's elapsed time is the old state's time + 1, that the new amount of minerals decreases by the amount required to build Building, and that I have a predicate can_build_new_building(Bs, B), which is true when a new building B can be built assuming that the buildings given in Bs are already built. I assume it is a non-deterministic predicate in general, and will yield all possible answers (= new buildings that can be built) on backtracking, and I leave it as an exercise for you to define such a predicate.

Given such a predicate state_successor/2, which relates a state of the world to its direct possible successors, you can easily define a path of states that lead to a desired final state. In its simplest form, it will look similar to the following DCG that describes a list of successive states:

states(State0) -->
     (   { final_state(State0) } -> []
     ;   [State0],
         { state_successor(State0, State1) },
         states(State1)
     ).

You can then use for example iterative deepening to search for solutions:

?- initial_state(S0), length(Path, _), phrase(states(S0), Path).

Also, you can keep track of states you already considered and avoid re-exploring them etc.

The reason you get confused with the example code you posted is essentially that build/1 does not have enough arguments to describe what you want. You need at least two arguments: One is the current state of the world, and the other is a possible successor to this given state. Given such a relation, everything else you need can be described easily. I hope this answers your question.

How to go about creating a prolog program that can work backwards to determine steps needed to reach a goal

2 Answers