Converting YUV422 to RGB using GPU shader HLSL

Question

I'm considering to perform the color space conversion from YUV422 to RGB using HLSL. A four-byte YUYV will yield 2 three-byte RGB values, for example, Y1UY2V will give R1G1B1(left pixel) and R2G2B2(right pixel). Given texture coordinates in pixel shader increased gradiently, how could I differentiate between the texture coordinates for the left pixels i.e. all R1G1B1 and the texture coordinates for right pixels i.e. all R2G2B2. This way I could render all R1G1B1 and all R2G2B2 on a single texture instead of two.

Thanks!

mrvux mrvux · Accepted Answer · 2013-09-07T17:01:33

Not sure what version of DirectX you use, but here is the version I use for dx11 (please note in that case I send yuv data in a StructuredBuffer, which saves me the fact of dealing with row stride. You can apply the same technique sending your yuv data as texture of course (with few little changes to the code below).

Here is the pixel shader code (I assume your render target is same size as your input image, and that you render a full screen quad/triangle).

StructuredBuffer<uint> yuy;

int w;
int h;

struct psInput
{
float4 p : SV_Position;
float2 uv : TEXCOORD0;
};

float4 PS(psInput input) : SV_Target
{
    //Calculate pixel location within buffer (if you use texture change lookup here)
uint2 xy = input.p.xy;
uint p = (xy.x) + (xy.y * w);
uint pixloc = p / 2;

uint pixdata = yuy[pixloc];

    //Since pixdata is packed, use some bitshift to remove non useful data
uint v  = (pixdata & 0xff000000) >> 24;
uint y1  = (pixdata & 0xff0000) >> 16;
uint u  = (pixdata & 0xff00) >> 8;
uint y0  = pixdata & 0x000000FF;

    //Check if you are left/right pixel
uint y = p % 2 == 0 ? y0: y1;

    //Convert yuv to rgb
float cb = u;
float cr = v;

float r  = (y + 1.402 * (cr - 128.0));
float g =  (y - 0.344 * (cb - 128.0) - 0.714 * (cr - 128));
    float b =  (y + 1.772 * (cb - 128));

return float4(r,g,b,1.0f) / 256.0f;
}

Hope that helps.

Converting YUV422 to RGB using GPU shader HLSL

1 Answers