Remap org-shiftmetaright | org-shiftmetaleft to [shift-select-meta]left-word | [shift-select-meta]right-word]

Question

Could someone please give me a hand remapping org-shiftmetaright | org-shiftmetaleft to [shift-select-meta]left-word | [shift-select-meta]right-word]. The goal is to highlight select region being a whole word (right or left) in one fell swoop in org-mode instead of changing the level of the headings. And not highlight when I release the shift, but nevertheless jump whole words to the left or right.

I would imagine that left-word and right-word probably have that caret "^" in the interactive command, or something similar, so there is no separate function for shift-left-word or shift-right-word.

(defvar custom-keys-mode-map (make-keymap) "custom-keys-mode keymap.")

(define-minor-mode custom-keys-mode
  "A minor mode so that my key settings override annoying major modes."
  t " my-keys" 'custom-keys-mode-map)

(custom-keys-mode 1)

(defun my-minibuffer-setup-hook ()
  (custom-keys-mode 0))

(add-hook 'minibuffer-setup-hook 'my-minibuffer-setup-hook)

(defadvice load (after give-my-keybindings-priority)
  "Try to ensure that my keybindings always have priority."
  (if (not (eq (car (car minor-mode-map-alist)) 'custom-keys-mode))
      (let ((mykeys (assq 'custom-keys-mode minor-mode-map-alist)))
        (assq-delete-all 'custom-keys-mode minor-mode-map-alist)
        (add-to-list 'minor-mode-map-alist mykeys))))

(ad-activate 'load)

;; (define-key custom-keys-mode-map (kbd "<C-key>") 'some-command)

(define-key custom-keys-mode-map (kbd "M-<left>") 'left-word)
(define-key custom-keys-mode-map (kbd "M-<right>") 'right-word)

(define-key custom-keys-mode-map (kbd "M-S-<left>") 'left-word)
(define-key custom-keys-mode-map (kbd "M-S-<right>") 'right-word)

EDIT: Here is the function from bindings.el that I'm looking to use in org-mode:

(defun right-word (&optional n)
  "Move point N words to the right (to the left if N is negative).

Depending on the bidirectional context, this may move either forward
or backward in the buffer.  This is in contrast with \\[forward-word]
and \\[backward-word], which see.

Value is normally t.
If an edge of the buffer or a field boundary is reached, point is left there
there and the function returns nil.  Field boundaries are not noticed
if `inhibit-field-text-motion' is non-nil."
  (interactive "^p")
  (if (eq (current-bidi-paragraph-direction) 'left-to-right)
      (forward-word n)
    (backward-word n)))

(defun left-word (&optional n)
  "Move point N words to the left (to the right if N is negative).

Depending on the bidirectional context, this may move either backward
or forward in the buffer.  This is in contrast with \\[backward-word]
and \\[forward-word], which see.

Value is normally t.
If an edge of the buffer or a field boundary is reached, point is left there
there and the function returns nil.  Field boundaries are not noticed
if `inhibit-field-text-motion' is non-nil."
  (interactive "^p")
  (if (eq (current-bidi-paragraph-direction) 'left-to-right)
      (backward-word n)
    (forward-word n)))

org-shiftmetaleft is a function. [shift-select-meta]left-word is...? — phils
That is my way of saying: shift+alt+left and shift+alt+right Those are what highlights/selects a word to left or right on OSX, and I think Windows also (but it has been a long time since I've used that OS). Essentially, I just need to disable the org-mode mapping of those keys and my previous attempts at disabling didn't work, so I thought of remapping. — lawlist
Better to use C-h k or C-h c to ask Emacs how to represent keys. <M-S-left> in this case. — phils
That is left-word which activates the "^" part of the interactive command so that it selects the region also. It works perfectly in text-mode and latex-mode, but org-mode overrides it. — lawlist
Well after org has loaded, naturally. Use org-mode-hook or do (eval-after-load "org" '(progn ...)) — phils

phils phils · Accepted Answer · 2013-07-09T05:05:05

As you just want to fall back to the default behaviour for these bindings, we can simply remove the org-mode overrides.

(eval-after-load "org"
  '(progn
     (define-key org-mode-map (kbd "<M-S-left>") nil)
     (define-key org-mode-map (kbd "<M-S-right>") nil)
     (define-key org-mode-map (kbd "<M-left>") nil)
     (define-key org-mode-map (kbd "<M-right>") nil)))

Remap org-shiftmetaright | org-shiftmetaleft to [shift-select-meta]left-word | [shift-select-meta]right-word]

3 Answers