Excel - VBA : pass variable from Sub to Userform

11
votes

I have read and applied solution I found on similar topics but nothing seem to work in my case.

So, I want to pass a variable from one sub of my Module1 to a userform. It's a string called "provinceSugg".

Here is the relevant part of my code : 

Public provinceSugg As String

Sub probaCity()
[...]
If province = "" And city <> "" Then
provinceSugg = sCurrent.Cells(p, db_column).Offset(0, 1).Value
UserForm2.Label1 = "Do you mean " & city & " in " & provinceSugg & " ?"
UserForm2.Label1.TextAlign = fmTextAlignCenter
UserForm2.Show
Else
End If

End Sub

And then in my userform code : 

Private Sub userformBtn1_Click()

MsgBox provinceSugg
sMain.Range("J6").Value = provinceSugg

End Sub

When I run my program :

1/ I have the content of provinceSugg showing in the MsgBox called from my sub (so there is a provinceSugg, it's not an empty variable).
2/ The MsgBox called from the userform is empty (so passing the value failed) and my program crashes when running " sMain.Range("J6").Value = provinceSugg" with something like "Error 424 Object Required" (so the variable failed to pass to the userform).

I tried all the stuff I found on forum and here (different ways to indicate that provinceSugg is a public variable but still crashing...).

Thanks in advance for your help !

2
excelvbavariablesuserform
Worked fine for me. Is there any other code running - such as the UserForm Initialisation - interering with provinceSugg? Can you post your workbook (sanitised if necessary)? – brettdj
@brettdj I have some updates: with this code in the button_click (" MsgBox provinceSugg sMain.Range("J6").Value = provinceSugg), I now have provinceSugg content displayed in the MsgBox but still nothing for the next line and the same error (object required/error 424), so the value is passed but can't be read in the second instruction... – Phalanx
If you try Sheets(x).Range("J6").Value = provinceSugg where x is the position of sMain does this work - I think this is your issue – brettdj
Oh geez I was so focused on provinceSugg that I completely forgot to take care of other objects! Thanks so much brettdj, that was indeed it ! – Phalanx
provinceSugg isnt the cause of the error in your case. Its the range that is not set. Please see this for further details – user2140173

2 Answers

11
votes

You would be able to create public variables within the Userform that can be set by the Module.

These variables are only accessible within the Userform as it is loaded.

Within the Userform, declare public variables for both objects.

Public sMain As Worksheet
Public provinceSugg as string

Private Sub userformBtn1_Click()

MsgBox provinceSugg
sMain.Range("J6").Value = provinceSugg

End Sub

Within the Module, you can assess both of those variables.

Sub probaCity()
[...]
If province = "" And city <> "" Then

    provinceSugg = sCurrent.Cells(p, db_column).Offset(0, 1).Value

    With UserForm2
        .provinceSugg = provinceSugg 
        Set .sMain = sMain 
        .Label1 = "Do you mean " & city & " in " & provinceSugg & " ?"
        .Label1.TextAlign = fmTextAlignCenter
        .Show
    End With

End If

End Sub
2
votes
Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Dim selectColumn
selectColumn= Split(Target.Address(1, 0), "$")(0)

Call UserFormStart(selectColumn)
End Sub

Inside Main Module

Public columnSelection As String
...
Public Sub UserFormStart(ByVal columnRef As String)
    'MsgBox "Debug columnRef=" & columnRef
    columnSelection = columnRef
    UserForm1.Show
End Sub

Inside UserForm

Private Sub UserForm_Initialize()

'MsgBox "Debug UserForm_Initialize =" & columnSelection
...

End Sub

Worksheet_SelectionChange calls a sub on the module where columnSelection is declared as public and visable from the UserForm. I used three different variables for the Column Reference to show that there is where the UserForm has access to the Module. The above all works and took ages to find and work out hence the submission. Happy hunting folks