How to form dbPedia iSPARQL query (for wikipedia content)

Question

Say I need to fetch content from wikipedia about all mountains. My target is to show initial paragraph, and an image from respective article (eg. Monte Rosa and Vincent Pyramid.

I came to know about dbpedia, and with some research got to find that it provides live queries into wiki database directly.

I have 2 questions:

1 - I am finding it difficult how could I formulate my queries. I can't play around iSPARQL. I tried following query but it throws error saying invalid xml.

SELECT DISTINCT ?Mountain FROM <http://dbpedia.org> WHERE {
  [] rdf:type ?Mountain 
}

2 - My requirement is to show only mountains that have at least 1 image (I need to show this image too). Now the ones I listed above have images, but how could I be sure? Also, looking at both examples I see many fields differ in wiki articles - so for future extension it maybe quite difficult to fetch them.

I just want to reject those which do not have sufficient data or description.

How can I filter out mountains based on pictures present?

UPDATE:

My corrected query, which solves my first problem:

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?name ?description
WHERE {
?name rdf:type <http://dbpedia.org/ontology/Mountain>;
dbpedia-owl:abstract ?description .
}

The query you wrote wouldn't search for mountains; rather it says, "find me all the triples of the form '_ rdf:type ?x' and give me back the list of each ?x". It's just asking for a list of types in the data. — Joshua Taylor
ok, got my query correct and now it returns mountain list correctly. Edited the answer. Still, my 2nd problem remains. — Nirav Bhatt
My answer includes a query for foaf:depiction so that things without a depiction aren't included. — Joshua Taylor

Joshua Taylor Joshua Taylor · Accepted Answer · 2013-05-23T18:50:50

You can also query dbpedia using its SPARQL endpoint (less fancy than iSPARQL). To find out more about what queries to write, take a look at the DBpedia's datasets page. The examples there show how one can select pages based on Wikipedia categories. To select resources in the Wikipedia Mountains category, you can use the following query:

select ?mountain where {
  ?mountain a dbpedia-owl:Mountain .
}

SPARQL Results

Once you have some of these links in hand, you can look at them in a web browser and see the data associated with them. For instance the page for Mount Everest shows lots of properties. For restricting results to those pages that have an image, you might be interested in the dbpedia-owl:thumbnail property, or perhaps better yet foaf:depiction. For the introductory paragraph, you probably want something like the dbpedia-owl:abstract. Using those, we can enhance the query from before. The following query finds things in the category Stratovolcanoes with an abstract and an depiction. Since StackOverflow is an English language site, I've restricted the abstracts to those in English.

select * where {
  ?mountain a dbpedia-owl:Mountain ;
            dbpedia-owl:abstract ?abstract ;
            foaf:depiction ?depiction .
  FILTER(langMatches(lang(?abstract),"EN"))
}
LIMIT 10

SPARQL Results

How to form dbPedia iSPARQL query (for wikipedia content)

1 Answers