TCL Variable Access Statistics

Question

What I want to do seems simple, but I don't know if the TCL interpreter has this functionality.

I have a tcl script that will have thousands of variables defined prior to running within its scope -- this is done by a pre-script that simply does a "global" on the thousands of variables to bring it into this current scope.

Is there an easy way to determine which of those thousands of variables were actually used during that script?

For instance, if the script has variables

a,b,c,d,e,

but only variable e was accessed (whether modified or just used), I would like to know.

slebetman slebetman · Accepted Answer · 2013-05-07T01:30:57

You can use tcl's trace capability to keep track of variable access.

Something like:

# at the end of the pre-script:

array set var_stats {}

proc track_var {varname n1 n2 op} {
    global var_stats
    incr var_stats($varname.$op)
}

foreach var $list_of_varnames {
    foreach op {array read write unset} {
        set var_stats($var.$op) 0
        trace add variable $var $op [list track_var $var]
    }
}

The code above will increment the appropriate stats (array, read, write and unset) for the variables when they are accessed. At the end of the script just dump the array with either an array get or a parray.

Updated answer:

I just reread your question and realize that if you just want to know which variable is accessed then there is a simpler way to do it:

array set var_stats {}

proc track_var {varname n1 n2 op} {
    global var_stats
    set var_stats($varname) 1
}

foreach var $list_of_varnames {
    trace add variable $var {array read write unset} [list track_var $var]
}

Then at the end of the script just do an array names to get a list of all variables accessed.

TCL Variable Access Statistics

1 Answers

Updated answer: