Match Columns on two excel worksheets and copy data

Question

I have two data sheets within the same excel file: Sheet1 as "Data" with 7 columns: enter image description here

The second sheet is "Main" with 5 columns: enter image description here

The same column to match the two files is "name". I want to have a VBA code that matches the name on both sheet and copy data from proc1 - Proc4 from sheet "Main" to sheet "data" by matching the column names on both sheets.

I searched stack overflow for similar question and here is the code that I found (modified it slightly):

Sub CopyData()

Dim shtImport As Worksheet
Dim shtMain As Worksheet
Set shtImport = ThisWorkbook.Sheets("Data")
Set shtMain = ThisWorkbook.Sheets("Main")

    Dim CopyColumn As Long
    Dim CopyRow As Long
    Dim LastColumn As Long

    '- for each column in row 1 of import sheet
    For CopyColumn = 1 To shtImport.Cells(1, shtImport.Columns.Count).End(xlToRight).Column
    '- check what the last column is with data in column
    LastRowOfColumn = shtImport.Cells(shtImport.Columns.Count, CopyColumn).End(xlToRight).Column
    'if last column was larger than one then we will loop through rows and copy
    If LastColumn > 1 Then
    For CopyRow = 1 To LastColumn
    '- note we are copying to the corresponding cell address, this can be modified.
    shtMain.Cells(CopyRow, CopyColumn).value = shtImport.Cells(CopyRow, CopyColumn).value
    Next CopyRow
    End If
    Next CopyColumn

    End Sub

This is not working the way I want it to work. Can somebody please help me with this problem. Thanks a lot!

I have also asked a similar question before but that was not looking for specific column name but column number. Can this code modified to include column name. I am not sure but thought it would be helpful to quote this here: stackoverflow.com/questions/14689156/… — datacentric

Kazimierz Jawor Kazimierz Jawor · Accepted Answer · 2013-04-04T17:33:09

Try this code:

Sub CopyData()

Dim shtImport As Worksheet
Dim shtMain As Worksheet
Set shtImport = ThisWorkbook.Sheets("Data")
Set shtMain = ThisWorkbook.Sheets("Main")

'From Main to Data
Dim rngImpTitles As Range
Set rngImpTitles = shtImport.Rows(1)
Dim rngImpNames As Range
Set rngImpNames = shtImport.Columns(1)

Dim CopyColumn As Long
Dim CopyRow As Long
Dim foundRow As Long
Dim foundCol As Long

On Error Resume Next
'for each column in row 1 of import sheet
For CopyColumn = 2 To shtMain.Cells(1, shtMain.Columns.Count).End(xlToLeft).Column
    foundCol = rngImpTitles.Find(shtMain.Cells(1, CopyColumn).Value2).Column
    If Err.Number <> 0 Then
        MsgBox "Not such a col title in importsheet for " & vbNewLine & _
                        shtMain.Cells(1, CopyColumn)
        Err.Clear
        GoTo skip_title
    End If


    For CopyRow = 2 To shtMain.Cells(shtMain.Rows.Count, 1).End(xlUp).Row
        foundRow = rngImpNames.Find(shtMain.Cells(CopyRow, 1)).Row
        If Err.Number <> 0 Then
            MsgBox "Not such a row name in importsheet for " & vbNewLine & _
                        shtMain.Cells(CopyRow, 1)
            Err.Clear
            GoTo skip_row
        End If

            If Len(shtMain.Cells(CopyRow, CopyColumn)) <> 0 Then
                    shtMain.Cells(CopyRow, CopyColumn).Copy shtImport.Cells(foundRow, foundCol)
            End If

skip_row:
    Next CopyRow
skip_title:
Next CopyColumn

End Sub

Match Columns on two excel worksheets and copy data

1 Answers