gnuplot script and smaller latex symbols

Question

I am usually using eps latex terminal and am passing LaTeX symbols surrounded by $$ $$ (i use the script below which i edit all the time).

If i want to make symbols smaller using {\tiny ... } it wont budge. So my question is: "How do i make latex symbols smaller?"

set terminal epslatex color colortext size 9cm,5cm
set size 1.5,1.0
set output "potencialna_jama_6.tex"

set xtics ("$0$" 0, "$\\frac{d}{2}$" 0.5, "$-\\frac{d}{2}$" -0.5)
set ytics ("$0$" 0)

set xlabel "$x$"

set style line 1 linetype 1 linewidth 3 linecolor rgb "#FF0055"
set style line 2 linetype 2 linewidth 1 linecolor rgb "#FF0055"
set style line 3 linetype 1 linewidth 3 linecolor rgb "#2C397D"
set style line 4 linetype 2 linewidth 1 linecolor rgb "#2C397D"
set style line 5 linetype 1 linewidth 3 linecolor rgb "#793715"
set style line 6 linetype 2 linewidth 1 linecolor rgb "#793715"
set style line 7 linetype 1 linewidth 3 linecolor rgb "#b1b1b1"
set style line 8 linetype 3 linewidth 1 linecolor rgb "#b1b1b1"

set grid

set samples 7000

set key at graph .70, 0.4
set key samplen 2
set key spacing 0.8

K=1
L=1
A=1

f(x) = A*exp(K*x)
g(x) = -( A*exp(-L*0.5) )/( sin(L*0.5) )*sin(L*x)
h(x) = -A*exp(-K*x)

set xrange [-1:1]
set yrange [-3:3]

plot [-1:1] f(x) ls 1 title "$\\psi_{I}$", g(x) ls 3 title "$\\psi_{II}$", h(x) ls 5 title "$\\psi_{III}$"

mgilson mgilson · Accepted Answer · 2013-04-02T13:37:25

As a disclaimer, I have almost no experience working with gnuplot's LaTeX terminals. However, with a little trial and error, I did something like this:

set xtics ("$0$" 0, "{\\tiny $\\frac{d}{2}$}" 0.5, "$-\\frac{d}{2}$" -0.5)

and I used the following TeX:

\documentclass{article}
\usepackage{graphicx}
\begin{document}
\begin {figure} 
  \begin{center} 
    \input{potencialna_jama_6} 
  \end{center} 
\end {figure}     
\end{document}

and lo and behold I got something which looked like:

enter image description here

Notice how the one x-tic label is significantly smaller than the others? Apparently {\\tiny ...} worked. Note that I needed to escape the leading \ for gnuplot's benefit (as you've done in numerous other places). I also didn't use color because my TeX complained about not knowing how to deal with colors, but I doubt that makes any real difference.

gnuplot script and smaller latex symbols

1 Answers