Can I convert a Clojure form from one package to another?

Question

Background

I've written a hack for Emacs that lets me send a Clojure form from an editor buffer to a REPL buffer. It's working fine, except that if the two buffers are in different namespaces the copied text doesn't usually make sense, or, worse, it might make sense but have a different meaning to that in the editor buffer.

I want to transform the text so that it makes sense in the REPL buffer.

A Solution in Common Lisp

In Common Lisp, I could do this using the following function:

;; Common Lisp

(defun translate-text-between-packages (text from-package to-package)
  (let* ((*package* from-package)
         (form (read-from-string text))
         (*package* to-package))
    (with-output-to-string (*standard-output*)
                           (pprint form))))

And a sample use:

;; Common Lisp

(make-package 'editor-package)
(make-package 'repl-package)

(defvar repl-package::a)

(translate-text-between-packages "(+ repl-package::a b)"
                                 (find-package 'editor-package)
                                 (find-package 'repl-package))
;; => "(+ A EDITOR-PACKAGE::B)"

The package name qualifications in the input string and the output string are different—exactly what's needed to solve the problem of copying and pasting text between packages.

(BTW, there's stuff about how to run the translation code in the Common Lisp process and move stuff between the Emacs world and the Common Lisp world, but I'm ok with that and I don't particularly want to get into it here.)

A Non-Solution in Clojure

Here's a direct translation into Clojure:

;; Clojure

(defn translate-text-between-namespaces [text from-ns to-ns]
  (let [*ns* from-ns
        form (read-string text)
        *ns* to-ns]
    (with-out-str
      (clojure.pprint/pprint form))))

And a sample use:

;; Clojure

(create-ns 'editor-ns)
(create-ns 'repl-ns)

(translate-text-between-namespaces "(+ repl-ns/a b)"
                                   (find-ns 'editor-ns)
                                   (find-ns 'repl-ns))
;; => "(+ repl-ns/a b)"

So the translation function in Clojure has done nothing. That's because symbols and packages/namespaces in Common Lisp and Clojure work differently.

In Common Lisp symbols belong to a package and the determination of a symbol's package happens at read time.

In Clojure, for good reasons, symbols do not belong to a namespace and the determination of a symbol's namespace happens at evaluation time.

Can This Be Done in Clojure?

So, finally, my question: Can I convert Clojure code from one namespace to another?

@sw1nn: I've just taken a quick look. I don't think there's anything there that would help — nothing about namespaces. This is about symbol resolution I think, which happens at evaluation time, not read time. — Simon K
Am confused. Why not eval the form in place -- tools like nrepl will do this in the correct namespace, so it all works. What results are you trying to achieve? If you want an interactive repl, then moving the current REPL to the namespace of the current buffer is also very easy. — Phil Lord
@PhilLord When demoing code or giving a presentation, it's often nice to send code to a REPL buffer. If I forget to set the REPL to have the right namespace, I'd like something sensible to happen. For now, if the REPL and current buffer have different namespaces, I ask for confirmation before sending text to the REPL. This is good enough, but it led me to the question I've posed here. — Simon K

A. Webb A. Webb · Accepted Answer · 2013-03-08T16:00:28

I don't understand your use case, but here is a way to transform symbols from one namespace to another.

(require 'clojure.walk 'clojure.pprint)

(defn ns-trans-form [ns1 ns2 form]
  (clojure.walk/prewalk
    (fn [f] (if ((every-pred symbol? #(= (namespace %) ns1)) f)
                (symbol ns2 (name f))
                f))
    form))

(defn ns-trans-text [ns1 ns2 text]
    (with-out-str
      (->> text 
           read-string 
           (ns-trans-form ns1 ns2) 
           clojure.pprint/pprint)))

(print (ns-trans-text "editor-ns" "repl-ns" "(+ editor-ns/a b)" ))
;=> (+ repl-ns/a b)

So, editor-ns/a was transformed to repl-ns/a.