Iterate recursively through nodes in a tree view?

6
votes

I have a tree view which is populated already with files/folders from another procedure. I would like to iterate one by one through the items in the tree view, going in exact order from top to bottom. However, unlike a normal list, I cannot use just a simple for statement for this. I have to go into each node, etc.

How do I do this? I'm hoping there's a way I can do it without running a recursive procedure. As I iterate through these items, I don't necessarily care about parent or child nodes of the currently focused one. I just need to be able to read the Data property of each node as I pass them, as well as highlight the current one in the tree view as I go through it. For each item in this tree view, I will be performing some work and want to visually display to the user which one is currently selected during this process.

2
delphirecursiontreeviewiteration
"I cannot use just a simple for statement for this" <- I'm having trouble understanding why? you are supposed to use a recursive function/procedure with a for loop in it's body, after the for loop you act on Node.Data property and the caller will move on to the next node and so on... – user497849
I said I cannot use a simple for statement for this, because there is no such thing as an item index or total node count in a tree view. – Jerry Dodge
it seems that David found your solution and a pretty clean one also... – user497849
@LURD The VCL is optimised so that sequential access by index is efficient. Random access is not. – David Heffernan
@LURD I only realised all this quite recently. I'd always used GetNext. Documentation is weak. – David Heffernan

2 Answers

16
votes

In fact you can use a for loop.

var
  Node: TTreeNode;
....
for Node in TreeView.Items do
  DoSomething(Node);

This is syntactic sugar for:

for i := 0 to TreeView.Items.Count-1 do
  DoSomething(TreeView.Items[i]);

In terms of readability I would recommend the for/in loop.

In older Delphi versions that don't support the node iterator you may prefer to do it with a while loop.

Node := TreeView.Items.GetFirstNode;
while Assigned(Node) do
begin
  DoSomething(Node);
  Node := Node.GetNext;
end;

I expect there are other ways to do it. These are the only ones that I know!

LU RD makes the interesting observation that the documentation states:

Accessing tree view items by index can be time-intensive, particularly when the tree view contains many items. For optimal performance, try to design your application so that it has as few dependencies on the tree view's item index as possible.

This is quite true. For random access the code has to walk the tree, starting at the root, until the ith node is located.

However, there is an optimisation for sequential access. The Delphi tree view wrapper remembers the index of the last node located by index. The next time you ask for a node with index no more than one different from the cached node, the required node can be returned quickly. This is implemented in TTreeNodes.GetNodeFromIndex.

3
votes
var
 i:Integer;
begin
  for I := 0 to tv.Items.Count - 1 do
      begin
        Listbox1.Items.Add(tv.Items[i].Text +' SubItems: ' + IntToStr(tv.Items[i].Count))
      end;

end;