Initialize values in AX 2012 Wizard controls…

Question

I have created a wizard in Ax 2012 using wizard>wizard and i am calling this wizard from Custtablelistpage form... now, i have put some controls in this wizard like CustAccount, and i need to initialize value in this control from selected record in Custtablelistpage form.... I am trying to perform this using Args class, but it is not working, please suggest some solutions..

please create one wizard in AX 2012 using tools>wizard>wizard then, please put menu item of this wizard somewhere on custtablelistpage. After that, please put one field named Customer account on welcome tab of wizard. Now, if you any record that is displayed in custtablelistpage form, please select that. My task is to display the Account num of selected record to my wizard when i am clicking the menu item button which i have put on custtablelistpage.

Actually, i have written some code,, which is is working absolutely fine for normal forms. but it is not working for Wizard and i am not getting value to initialize in my control on wizard.

[axaptapedia.com/Passing_values_between_forms] the code is similar as mentioned in above link... and the code is working fine when passing selected record to a normal form from custtablelistpage but not when passing the record or parameter to Wizard.... please create a wizard and use it as a menuitembutton on a custtablelistpage and try it yourself and let me know if you figure out the issue.. i'll be thankful to you.... — Mohd Saddaf khan
Have you tried passing the AccountNum through the parm method in Args? msdn.microsoft.com/en-us/library/xargs.parm.aspx — SShaheen
@SShaheen Yes i have already tried that...As ai already mentioned that it is working for normal forms but not when using wizard.. — Mohd Saddaf khan

Kenny Saelen Kenny Saelen · Accepted Answer · 2012-12-21T14:01:25

Ok, I took some time to try this out and I have two possible solutions for you.

You can do it by using unbound controls and pass in the selected record
Or you could use a datasource on the wizard form and filter on the selected values

First let's try and do it by using a simple unbound control. Start by adding a CustTable member variable and parameter method to your wizard class.

public class MyTestWizardWizard extends SysWizard
{
    CustTable   mySelectedCustomer;
}

public CustTable parmMySelectedCustomer(CustTable _mySelectedCustomer = mySelectedCustomer)
{
    ;
    mySelectedCustomer = _mySelectedCustomer;
    return mySelectedCustomer;
}

Then in your form, you can overwrite the init method and do the following :

void init()
{
    int                 controlid;
    FormStringControl   fsControl;
    ;

    super();

    if (element.Args().caller())
    {
        sysWizard = element.Args().caller();

        // Get the control id of the CustomerId control 
        controlid = element.controlId(formControlStr(MyTestWizardWizard, CustomerId));  

        // Check if we actually have a form string control
        if(element.control(controlid) is FormStringControl)
        {
            // Cast to the FormStringControl type
            fsControl = element.control(controlid) as FormStringControl;

            // Now fill in the field value
            fsControl.text(sysWizard.parmMySelectedCustomer().AccountNum);
        }
    }
    else
    {
        MyTestWizardWizard::main(new args());
        element.closeCancel();
    }
}

So what you actually do here is just fetch the selected record stored in you wizard class. Then we check if the control we want to assign values to is actually the right control to put the value in.

Though this is working, I would prefer a second method. That would be to use a datasource on the form and put a range on the selected record like this. Just put the CustTable as a datasource on the form and place your control as you would normally do.

Then, make sure the init method is performing the super() call at the bottom to make sure initialisation is done before calling the datasource methods:

void init()
{
    ;

    // make sure the sysWizard is already initialized before the super to make sure the init on the datasource has an instance of sysWizard
    if (element.Args().caller())
    {
        sysWizard = element.Args().caller();
    }
    else
    {
        MyTestWizardWizard::main(new args());
        element.closeCancel();
    }

    super();
}

Then overwrite the init method on the datasource to put a range on the recId field of the custTable. Please mind the you could assign the value of the range in the ExecuteQuery method, but for this case, I just do it here.

public void init()
{
    ;
    super();

    SysQuery::findOrCreateRange(this.query().dataSourceTable(tableNum(CustTable)), fieldNum(CustTable, RecId)).value(queryValue(SysWizard.parmMySelectedCustomer().RecId));
}

Now when your wizard is run, the args passes the record to your wizard class, the form picks it up on the init of the datasource and puts a range on the record that you have selected. All the rest of the magic is normal Ax behavior with bound data controls.

So I hope this is what you needed. Please let me know if you have further questions.

Initialize values in AX 2012 Wizard controls…

1 Answers