regex to match word boundary beginning with special characters

Question

I have regex that matches words fine except if they contain a special character such as ~Query which is the name of a member of a C++ class. Need to use word boundary as shown below for member names that are single characters. $key =~ /\b$match\b/

I tried numerous expressions I thought would work such as /[~]*\b$match\b/ or /\b[~]*$match\b/

Is it possible to put a word boundary on words that may contain a special character?

Can you post exactly what you want to match.. Regex are generated for specific cases, not just by assuming what your string is.. — Rohit Jain
/~\b$match\b/ should match ~Query, assuming that the regex contained in $match would match Query. (I just tested, and " ~foo " =~ /~\bfoo\b/ evaluates as true.) — cdhowie
$match variable might contain ~Query, Query, or single letter such as p. Are possibly any other strange name developers use for their class methods. Regex is part of a subroutine that is doing a search. All works fine except when $match contains ~Query. — Jeff Cunningham

ikegami ikegami · Accepted Answer · 2012-10-03T16:31:23

\b

is short for

(?:(?<!\w)(?=\w)|(?<=\w)(?!\w))

If you want to treat ~ as a word character, change \w to [\w~].

(?:(?<![\w~])(?=[\w~])|(?<=[\w~])(?![\w~]))

Example usage:

my $word_char = qr/[\w~]/;
my $boundary  = qr/(?<!$word_char)(?=$word_char)
                  |(?<=$word_char)(?!$word_char)/x;

$key =~ /$boundary$match$boundary/

If we know $match can only match something that starts and ends with a $word_char, we can simplify as follows:

my $word_char   = qr/[\w~]/;
my $start_bound = qr/(?<!$word_char)/;
my $end_bound   = qr/(?!$word_char)/;

$key =~ /$start_bound$match$end_bound/

This is simple enough that we can inline.

$key =~ /(?<![\w~])$match(?![\w~])/

regex to match word boundary beginning with special characters

2 Answers