XML ArrayCollection applicationStorageDirectory

Question

I have an XML file that I lives in the applicationStorageDirectory, I need to load the contents into an ArrayCollection.

The XML looks like (see below), I can read and write to it but I need to stick the data in an ArrayCollection so I can load it into a datagrid.

<?xml version="1.0" encoding="utf-8"?>
<item>
 <sort>2012/10/31PM0000</sort>
 <date>Wed Oct 31 2012</date>
 <event>Halloween</event>
 <time>12:00 PM</time>
</item>
<item>
  <sort>2012/09/13AM0000</sort>
  <date>Thu Sep 13 2012</date>
  <event>Enter Details</event>
  <time>12:00 AM</time>
</item>

I've found I can use url="app-storage:/reminder.xml" in HTTP service and it works with Air, dunno about an android app, will have to wait and see.

<s:HTTPService id="reminderXML" url="app-storage:/reminder.xml" result="reminderDataHandler(event)" fault="faultHandler(event);"/>

Tianzhen Lin Tianzhen Lin · Accepted Answer · 2012-09-14T04:08:09

You may give the following util a try, which would convert your XML/XMLList to ICollectionView. You can use it to bind to datagrid.

    public static function toCollection( value:Object ):ICollectionView
    {
        var collection:ICollectionView;

        collection = null;
        if (value is Array)
        {
            collection = new ArrayCollection(value as Array);
        }
        else if (value is ICollectionView)
        {
            collection = ICollectionView(value);
        }
        else if (value is IList)
        {
            collection = new ListCollectionView(IList(value));
        }
        else if (value is XMLList)
        {
            collection = new XMLListCollection(value as XMLList);
        }
        else if (value is XML)
        {
            var xl:XMLList = new XMLList();
            xl += value;
            collection = new XMLListCollection(xl);
        }
        else
        {
            // convert it to an array containing this one item
            var tmp:Array = [];
            if (value != null)
                tmp.push(value);
            collection = new ArrayCollection(tmp);
        }

        return collection;
    }

XML ArrayCollection applicationStorageDirectory

1 Answers