Is it possible to use a pointer in type constructor in fortran?

Question

In some Fortran 95 code, I have a type with a pointer field. I want to declare a module variable of type(foo) which is initialized at compile-time. Something like this:

module foo_module
  implicit none
  type foo_type
     integer :: x
     logical, pointer :: x_flag => null()
  end type foo_type

  logical, target :: bar_flag
  ! this does not compile of course:
  type(foo_type) :: bar = foo_type(1, bar_flag)
end module foo_module

The snippet above does not compile. I understand that I can initialize bar at run time using a separate subroutine, like:

module foo_module
  implicit none
  type foo_type
     integer :: x
     logical, pointer :: x_flag => null()
  end type foo_type

  logical, target :: bar_flag
  type(foo_type) :: bar
contains
  subroutine init()
    bar%x = 1
    bar%x_flag => bar_flag
  end subroutine init
end module foo_module

But is it possible to do this without an initialization subroutine? Or is it possible to declare an initialization subroutine which is called explicitly by the compiler? Note: this must be done in Fortran 95.

IanH IanH · Accepted Answer · 2012-08-10T18:18:46

An initializer (the thing appearing after the equals in the declaration of bar in the first block of example code) must be a initialization (constant) expression. The rules for initialization expressions in Fortran 95 do not permit pointer targets other than NULL() in structure constructors.

(This rule was relaxed in Fortran 2008 to permit pointer targets in structure constructors in initialization expressions to be variables with the save attribute.)

Note that your init subroutine could use a structure constructor instead of assignment to the individual components. Client code using the module could also directly execute the assignment to bar using a structure constructor: bar = foo_type(1, bar_flag). The issue is not the use of a pointer target in a structure constructor - it is the appearance of a pointer target in a structure constructor in a place where it must be an initialization expression.

It is not possible to declare an initialization procedure for a derived type. (It is possible in Fortran 2003 to have a function that overrides a structure constructor, but such a function cannot be used in an initialization expression.)

Is it possible to use a pointer in type constructor in fortran?

1 Answers