Change active microphone in AS3

Question

Is there a way to change the active microphone in AS3 without using the SecurityPanel.MICROPHONE? All of my attempts stop all microphone activity, even if triggered by a button click.

If I do:

var mic:Microphone = Microphone.getMicrophone(index);

I can listen and get microphone activity, level and SampleEvents. All works well.

If at a later point I do:

mic = Microphone.getMicrophone(newIndex);

I start getting -1 for mic.activityLevel and receive no SampleEvents, but I can get the proper name of the new mic with

mic.name;

For simplicity assume that index and newIndex are both working sources that have been tested, and either work if passed in with the initial microphone request.

Is this viewed as a security risk and not allowed? Once you initialize one mic, is that what you are stuck with? I have switched cameras in air, but that was air.

*as a side note, I can not use the SecurityPanel to do this because of the potential for feedback when accessed from FireFox on osx if the computer is hooked to speakers. I have tried dropping all sound output to 0 before opening the window, but the level comes back up as soon as SecurityPanel.MICROPHONE is active. Unfortunately, just asking the users to turn down their speakers, is not an option.

You can switch microphones after the user has already granted access. Are you by any chance using the enhanced microphone? There can be difficulties w/using multiple mics when using the enhanced mic. — Sunil D.
Just a silly question, are you adding new event listeners after doing mic = Microphone.getMicrophone(newIndex);? — bmleite
Sunil D. - I get this problem after someone has granted access, but not using the enhanced mic. — smilinfoo
bmleite - Good lord I may not be, will check on Monday. This could be the most embarrassing thing I have done in a while. — smilinfoo
Unfortunately, it is not the listeners. As a test I am polling a var _mic:Microphone, with _mic.activityLevel every .1 sec. and every 3 seconds, I update the _mic variable to a different mic with _mic=getMicrophone(_newIndex);. If I am switching back and forth between 2 mics, whichever was last selected in the securityPanel with be active when I switch to it, but the other never returns anything but -1. — smilinfoo

Benoit Beausejour Benoit Beausejour · Accepted Answer · 2012-08-09T17:44:55

From my experience there are two reasons that can cause the activityLevel to report -1 :

1.The user did not accept the security permissions

This is detectable with StatusEvent.STATUS and checking the mic.muted property.

mic.addEventListener(StatusEvent.STATUS, onMicrophoneStatus, false, 0, true);

private function onMicrophoneStatus(event:StatusEvent):void
{           
    if (event.code == "Microphone.Unmuted") 
        trace("Microphone access was allowed."); 
    else if (event.code == "Microphone.Muted") 
        trace("Microphone access was denied."); 
}

2.The second reason seems to be more esoteric and is related to two things. Wether or not the microphone went into loopback mode ; and if the microphone has a *SampleDataEvent.SAMPLE_DATA* listener.

I can't really explain precisely the logic behind it, but I suppose that sending the microphone into loopback mode initializes some event logic. You could even do mic.setLoopBack(true); mic.setLoopBack(false);.

I wish someone could explain what is actually going in the background.

3.For you second issue related to the huge echo when the panel opens, rockabit found a nice trick to fix this. You have to set the SoundTransform property of the microphone to a soundtransform object with a volume of 0. This allows you to keep your microphone into loopback mode but prevent the huge echo and feedback as well as remove the microphone captured sound from the output.

Here's the thread for reference: http://www.rockabit.com/2009/01/14/microphone-activitylevel-in-flash/

Finally, here's a snippet of code I use to initialize my microphone that works even when swapping mics: (snipped for clarity)

private function initializeMicrophone(micIndex:int = 0):void
{   
    trace("Initialize mic: "+micIndex);

    var gain:int = 70;
    var rate:int = 44;
    var silence:int = 0;
    var timeout:int = 100;

    this.microphone = Microphone.getEnhancedMicrophone(micIndex);
    mic.addEventListener(StatusEvent.STATUS, onMicrophoneStatus, false, 0, true);
    mic.addEventListener(SampleDataEvent.SAMPLE_DATA, onSampleData);

    mic.gain = gain;
    mic.setSilenceLevel(silence, timeout);
    mic.rate = rate;

    var micXform:SoundTransform = new SoundTransform(0);
    mic.soundTransform = micXform;

    mic.codec = SoundCodec.NELLYMOSER;
    mic.setUseEchoSuppression(true);
    mic.setLoopBack(true);

    var micOptions:MicrophoneEnhancedOptions = new MicrophoneEnhancedOptions();
    micOptions.mode = MicrophoneEnhancedMode.FULL_DUPLEX;
    micOptions.nonLinearProcessing = true;
    micOptions.echoPath = 128;
    mic.enhancedOptions = micOptions;
}

private function onSwapMicrophone():void
{
    if(this.mic.index == 0)
      initializeMicrophone(1);
    else
      initializeMicrophone(0);
}

Hope this helps!

-b

Change active microphone in AS3

1 Answers