How to create transparent png image from bitmap?

Question

My task is:

Create a TBitmap object.
Fill it with transparent color (alpha = 0).
Assign this bitmap to TPngImage.
Save PNG file with alpha transparency.

How can I do it in Delphi XE?

var
  Png: TPngImage;
  X, Y: Integer;
  Bitmap: TBitmap;
begin
  Bitmap := TBitmap.Create();
  Bitmap.PixelFormat := pf32bit;
  Png := TPngImage.Create();
  try
    Bitmap.SetSize(100, 100);

    // How to clear background in transparent color correctly?
    // I tried to use this, but the image in PNG file has solid white background:
    for Y := 0 to Bitmap.Height - 1 do
      for X := 0 to Bitmap.Width - 1 do
        Bitmap.Canvas.Pixels[X, Y]:= $00FFFFFF;

    // Now drawing something on a Bitmap.Canvas...
    Bitmap.Canvas.Pen.Color := clRed;
    Bitmap.Canvas.Rectangle(20, 20, 60, 60);

    // Is this correct?
    Png.Assign(Bitmap);
    Png.SaveToFile('image.png');
  finally
    Png.Free();
    Bitmap.Free();
  end;
end;

Just one sidenote, don't use TCanvas.Pixels, it's terribly slow and evil ;-) Use TBitmap.Scanline instead. — TLama
See this answer to the question How to save a png file with transparency? for an example. — LU RD
Another sidenote, do you even need a bitmap ? Don't you want to render what you need directly on a PNG image canvas ? — TLama
@LURD Thanks, now I understand how to fill with transparent color: by settings Bitmap.TransparentColor and Bitmap.Transparent after filling background. Can you add this as answer please? — Andrew
@Andrew, you need to instantiate the TPNGImage by using CreateBlank not by Create to make its canvas drawable. — TLama

LU RD LU RD · Accepted Answer · 2012-06-13T11:11:49

More or less a copy of Dorin's answer. It shows how to make a transparent png image and how to clear the background.

uses
  PngImage;
...

var
  bmp: TBitmap;
  png: TPngImage;
begin
  bmp := TBitmap.Create;
  bmp.SetSize(200,200);

  bmp.Canvas.Brush.Color := clBlack;
  bmp.Canvas.Rectangle( 20, 20, 160, 160 );

  bmp.Canvas.Brush.Style := bsClear;
  bmp.Canvas.Rectangle(1, 1, 199, 199);

  bmp.Canvas.Brush.Color := clWhite;
  bmp.Canvas.Pen.Color := clRed;
  bmp.Canvas.TextOut( 35, 20, 'Hello transparent world');

  bmp.TransparentColor := clWhite;
  bmp.Transparent := True;

  png := TPngImage.Create;
  png.Assign( bmp );
  png.SaveToFile( 'C:\test.png' );

  bmp.Free;
  png.Free;
end;

How to create transparent png image from bitmap?

1 Answers