To remove the node but keep the value inside intact through XQuery

1
votes

I have a content.xml modelled as below

<root>
  <childnode>
    Some text here
  </childnode>
</root>

I am trying to remove the <childnode> and update the content.xml with only the value of it so the output looks like

<root>
  Some Text here
</root>

I wrote a function to perform this but anytime I run it it gives me error as "unexpected token: modify". I was thinking of a way to accomplish this without using functx functions. 

xquery version "1.0";    

declare namespace request="http://exist-db.org/xquery/request";  
declare namespace file="http://exist-db.org/xquery/file";  
declare namespace system="http://exist-db.org/xquery/system";
declare namespace util="http://exist-db.org/xquery/util";
declare namespace response="http://exist-db.org/xquery/response";

declare function local:contentUpdate()  {
    let $root := collection('/lib/repository/content')//root/childNode
    let $rmChild := for $child in $root
    modify
    (
    return rename node $child as ''
    )
};

local:updateTitle()

Thanks in advance

2
xqueryexist-db
Sorry this did not come up in my question. This is the content.xml and expected output. Content.xml <root> <childnode> Some Text here </childnode> </root> Expected Output <root> <childnode> Some Text here </childnode> </root> - Joe
I reformatted your question to include the correct code, but is still waiting for approval. - Jens Erat

2 Answers

0
votes

There are multiple problems with your query:

  1. Updating functions must be declared as updating.
  2. You're calling another function than you defined (probably you didn't notice as there still have been syntax errors).
  3. Rename node expects some element (or processing instruction, attribute) as target, the empty string is not allowed.
  4. At least BaseX doesn't allow updating statements when defining code as XQuery 1.0. Maybe exist doesn't care about this, try adding it if you need to know.

You do not want to rename, but replace all <childnode />s with its contents, use replace node.

This code fixes all these problems:

declare updating function local:contentUpdate()  {
  let $root := collection('/lib/repository/content')
  return 
    for $i in $root//childnode
    return
      replace node $i with $i/data()
};

local:contentUpdate()
0
votes

eXist-db's XQuery Update syntax is documented at http://exist-db.org/exist/update_ext.xml. Note that this syntax predates the release of the XQuery Update Facility 1.0, so the syntax is different and remains unique to eXist-db.

The way to do what you want in eXist-db is as follows:

xquery version "1.0";

declare function local:contentUpdate()  {
    let $root := doc('/db/lib/repository/content/content.xml')/root
    return
        update value $root with $root/string()
};

local:contentUpdate()

The primary changes, compared to your original code, are:

  1. Inserted the eXist-db syntax for your update
  2. Prepended '/db' to your collection name, as /db is the root of the database in eXist-db; replaced the collection() call with a doc() call, since you stated you were operating on a single file, content.xml
  3. Changed //root to /root, since "root" is the root element, so the // (descendant-or-self) axis is extraneous
  4. Replaced updateTitle() with the actual name of the function, contentUpdate
  5. Removed the extraneous namespace declarations

For more on why I used $root/string(), see http://community.marklogic.com/blog/text-is-a-code-smell.