Omit empty elements from XSLT 1.0 output

Question

I'm using XSLT 1.0 to transform an XML document to a different schema of XML. The source document may or may not have elements depending on the source database it is built from.

EG

   <Patients>
        <Patient id="1019">
            <Surname>Acqua</Surname>
            <Forenames>Matthew James</Forenames>
            <VoicePhone>0111 222 33333</VoicePhone>
        </Patient>
        <Patient id="1020">
            <Surname>Red</Surname>
            <Forenames>James Alan</Forenames>
        </Patient>
    </Patients>

The resulting output after transforming via XML will have empty elements in it because the VoicePhone in the second patient doesn't exist (rather than exist but is empty).

The XSLT is along these lines:

<xsl:template match="//Patients/Patient">
<PatientRxs>
  <PatientInfo>
    <FirstName>
      <xsl:value-of select="Forenames"/>
    </FirstName>
    <Telephone>
      <xsl:value-of select="VoicePhone"/>
    </Telephone>
  </PatientInfo>
</PatientRxs>
</xsl:template>

And I end up with:

<PatientRxs>
    <PatientInfo>
        <FirstName>Matthew James</FirstName>
        <Telephone>0111 222 33333</Telephone>
    </PatientInfo>
</PatientRxs>
<PatientRxs>
    <PatientInfo>
        <FirstName>James Alan</FirstName>
        <Telephone/>
    </PatientInfo>
</PatientRxs>

Where I actually want:

<PatientRxs>
    <PatientInfo>
        <FirstName>Matthew James</FirstName>
        <Telephone>0111 222 33333</Telephone>
    </PatientInfo>
</PatientRxs>
<PatientRxs>
    <PatientInfo>
        <FirstName>James Alan</FirstName>
    </PatientInfo>
</PatientRxs>

Although I could test if the value exists this is just 1 of hundreds of elements that could potentially not exist in the source document and would like to avoid having an XSLT sheet testing every single one of them

Answer 1

Try having a generic template that matches any element, but takes a parameter to allow that element to be renamed

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="xml" indent="yes" />
  <xsl:strip-space elements="*" />

  <xsl:template match="//Patients/Patient">
    <PatientRxs>
      <PatientInfo>
        <xsl:apply-templates select="Forenames" mode="field">
          <xsl:with-param name="newName" select="'FirstName'" />
        </xsl:apply-templates>
        <xsl:apply-templates select="VoicePhone" mode="field">
          <xsl:with-param name="newName" select="'Telephone'" />
        </xsl:apply-templates>
      </PatientInfo>
    </PatientRxs>
  </xsl:template>

  <xsl:template match="*" mode="field">
      <xsl:param name="newName" select="local-name()" />

      <xsl:element name="{$newName}">
          <xsl:value-of select="." />
      </xsl:element>
  </xsl:template>

</xsl:stylesheet>

So, if the element being matched does not exist, nothing gets output for that element at all.

Answer 2

<xsl:template match="Patients">
        <xsl:element name="PatientRxs">
            <xsl:for-each select="Patient">
                <xsl:element name="PatientInfo">
                    <xsl:element name="Forenames">
                        <xsl:value-of select="Forenames"/>
                    </xsl:element>
                    <xsl:if test="VoicePhone">
                        <xsl:element name="Telephone">
                            <xsl:value-of select="VoicePhone"/>
                        </xsl:element>
                    </xsl:if>
                </xsl:element>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
Test if Voicephone exist then insert element otherwise not.

Answer 3

<xsl:template match="Patients">
        <xsl:element name="PatientRxs">
            <xsl:for-each select="Patient">
                <xsl:element name="PatientInfo">
                    <xsl:element name="Forenames">
                        <xsl:value-of select="Forenames"/>
                    </xsl:element>
                    <xsl:apply-templates select="VoicePhone"/>
                        </xsl:element>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
    <xsl:template match="VoicePhone">
        <xsl:choose>
            <xsl:when test="text()">
                <xsl:element name="Telephone">
                    <xsl:value-of select="."/>
                </xsl:element>
            </xsl:when>
            <xsl:when test="empty(.)"/>
        </xsl:choose>
      </xsl:template>

Try this one